异常类别包括：

使用异常处理程序进行错误处理使程序更易编写和理解，并减少未处理异常的可能性。 如果没有异常处理程序，您必须在可能发生错误的每个地方检查每个可能的错误，然后处理它。 特别是如果错误不能立即检测到，很容易忽略可能的错误或可能发生错误的地方。 错误处理代码分散在整个程序中。 有了异常处理程序，您不需要知道每个可能的错误或可能发生错误的地方。 您只需要在可能发生错误的每个块中包含一个异常处理部分。 在异常处理部分中，您可以包括针对特定和未知错误的异常处理程序。 如果块中的任何位置（包括子块内部）发生错误，则异常处理程序将处理它。 错误处理代码隔离在块的异常处理部分中。

目前 pl/sql 支持预定义错误和用户定义错误。

INVALID_CURSOR 主要针对两种情况：显式游标和游标变量。

--preconditional
create table employees(id int, name varchar2(100), job varchar2(100));
insert into employees values (22091401, 'sunli', 'actress');
insert into employees values (22091402, 'dengchao', 'actor');
insert into employees values (22091403, 'lishizhen', 'doctor');
insert into employees values (22091404, 'zhangsanfeng', 'martial artist');

create or replace function invalid_cursor_f return int as
   cursor c1 is select * from  employees;
   emp_cur employees%rowtype;
begin
    open c1;
    loop
      fetch c1 into emp_cur;
      exit when c1%notfound;
      close c1;
    end loop;
    close c1;
EXCEPTION
  WHEN invalid_cursor THEN
    DBMS_OUTPUT.PUT_LINE('invalid cursor');
    return 1;
end;
/

select invalid_cursor_f();
    

create or replace function invalid_cursor_f return int as
   cursor c1 is select * from  employees;
   emp_cur employees%rowtype;
   ora_found boolean := false;
begin
   ora_found := c1%found;
EXCEPTION
  WHEN invalid_cursor THEN
    DBMS_OUTPUT.PUT_LINE('invalid cursor');
   return 1;
end;
/

select invalid_cursor_f();
    

create or replace function invalid_cursor_f return int as
   c1 sys_refcursor;
   emp_cur employees%rowtype;
begin
    open c1 for select * from  employees;
    loop
      fetch c1 into emp_cur;
      exit when c1%notfound;
      close c1;
    end loop;
    close c1;
EXCEPTION
  WHEN invalid_cursor THEN
    DBMS_OUTPUT.PUT_LINE('invalid cursor');
    return 1;
end;
/

select invalid_cursor_f();
    

create or replace function invalid_cursor_f return int as
   c1 sys_refcursor;
   emp_cur employees%rowtype;
   ora_isopen boolean := false;
begin
  ora_isopen := c1%isopen;
  return 1;
  exception 
    when INVALID_CURSOR then
      dbms_output.put_line('this is a normal error');
end;
/

select invalid_cursor_f();
    

case语句，如果when子句中没有包含必要的条件分支，就会触发CASE_NOT_FOUND异常。简单情况下有simple_case_statement，搜索情况下有search_case_statement。

例如，简单情况下的simple_case_statement。

create or replace function case_not_found_f return int as
  grade CHAR(1);
BEGIN
  grade := 'G';
  
  CASE grade
    WHEN 'A' THEN DBMS_OUTPUT.PUT_LINE('Excellent');
    WHEN 'B' THEN DBMS_OUTPUT.PUT_LINE('Very Good');
    WHEN 'C' THEN DBMS_OUTPUT.PUT_LINE('Good');
    WHEN 'D' THEN DBMS_OUTPUT.PUT_LINE('Fair');
    WHEN 'F' THEN DBMS_OUTPUT.PUT_LINE('Poor');
  END CASE;
EXCEPTION
  WHEN CASE_NOT_FOUND THEN
    DBMS_OUTPUT.PUT_LINE('No such grade');
  return 1;
END;
/

select case_not_found_f();
    

例如，搜索情况下的search_case_statement。

create or replace function case_not_found_f return int as
  grade CHAR(1);
BEGIN
  grade := 'G';
  
  CASE
    WHEN grade = 'A' THEN DBMS_OUTPUT.PUT_LINE('Excellent');
    WHEN grade = 'B' THEN DBMS_OUTPUT.PUT_LINE('Very Good');
    WHEN grade = 'C' THEN DBMS_OUTPUT.PUT_LINE('Good');
    WHEN grade = 'D' THEN DBMS_OUTPUT.PUT_LINE('Fair');
    WHEN grade = 'F' THEN DBMS_OUTPUT.PUT_LINE('Poor');
  END CASE;
EXCEPTION
  WHEN CASE_NOT_FOUND THEN
    DBMS_OUTPUT.PUT_LINE('No such grade');
  return 1;
END;
/

select case_not_found_f();
    

当向唯一索引对应的列插入重复值时触发。

例如:

--preconditional
CREATE TABLE emp_name AS SELECT id, name FROM employees;

CREATE UNIQUE INDEX empname_ix ON emp_name (id);

create or replace procedure dup_val_on_index_p as
  emp_id        NUMBER(10);
  emp_name  VARCHAR2(100);
BEGIN
  SELECT id, name  INTO emp_id, emp_name FROM employees WHERE id = 22091401;
 
  INSERT INTO emp_name (id, name) VALUES (emp_id, emp_name);
 
EXCEPTION
  WHEN DUP_VAL_ON_INDEX THEN
    ROLLBACK;
    DBMS_OUTPUT.PUT_LINE('Inserts were rolled back');
END;
/

call dup_val_on_index_p();
    

当执行select into时没有返回任何行时触发。

例如:

-- no_data_found
-- select into
-- number of record selected is zero
create or replace function no_data_found_f return int as
  v_emp int;
begin
  select id into v_emp from employees where id = 22091501;
EXCEPTION
  WHEN no_data_found THEN
    DBMS_OUTPUT.PUT_LINE('No data found');
  return 1;
end;
/

select no_data_found_f();
    

当执行select into语句时，如果返回超过一行，则会触发TOO_MANY_ROWS异常。

例如:

create or replace function too_many_rows_f return int as
  v_emp int;
begin
  select id into v_emp from employees;

EXCEPTION
  WHEN no_data_found THEN
    DBMS_OUTPUT.PUT_LINE('No data found');
  WHEN too_many_rows THEN
    DBMS_OUTPUT.PUT_LINE('Too Many Rows');

  return 1;
end;
/

select too_many_rows_f();
    

你可以使用raise来抛出预定义的异常，并在异常后处理问题。（在pl/sql中不会触发，但在LightDB中会触发）

例如：

create or replace function login_denied_f return int as
begin
  raise login_denied;
exception
  when login_denied then
    dbms_output.put_line('this is a login_denied message.. good luck the next time');
  return 1;
end;
/

select login_denied_f();
    

当除数为0时，被除数不为0的数字执行除法的事件就会触发该异常。

例如：

create or replace function zero_divide_f return int as
    a int := 10;
    b int := 0;
begin
    a := a / b;
    exception 
      when zero_divide then
        dbms_output.put_line('this is a normal error');
    return 1;
end;
/

select zero_divide_f();